Viewing snippet of RRXXH | Workshop.codes

settings
{
main
{
Description: "banhammer - RRXXH"
}
lobby
{
Allow Players Who Are In Queue: Yes
Map Rotation: After A Game
Match Voice Chat: Enabled
Max Spectators: 12
Max Team 1 Players: 11
Max Team 2 Players: 1
Return To Lobby: Never
Team Balancing: After A Game
}
modes
{
Skirmish
{
disabled maps
{
Workshop Chamber
Workshop Expanse
Workshop Expanse Night
Workshop Green Screen
Workshop Island
Workshop Island Night
}
}
General
{
Health Pack Respawn Time Scalar: 10%
Kill Cam: Off
Kill Feed: Off
Spawn Health Packs: Enabled
}
}
heroes
{
Team 1
{
Jump Vertical Speed: 125%
Movement Gravity: 80%
disabled heroes
{
Reinhardt
}
}
Team 2
{
Ability Cooldown Time: 300%
Damage Dealt: 211%
Health: 500%
Jump Vertical Speed: 180%
enabled heroes
{
Reinhardt
}
}
General
{
Movement Speed: 150%
Mei
{
Ammunition Clip Size Scalar: 300%
Weapon Freeze Duration Scalar: 200%
Weapon Freeze Rate Scalar: 40%
}
Reinhardt
{
Barrier Field: Off
Charge Knockback Scalar: 0%
Fire Strike: Off
Quick Melee: Off
Rocket Hammer Knockback Scalar: 400%
Ultimate Generation - Combat Earthshatter: 75%
Ultimate Generation - Passive Earthshatter: 125%
}
}
}
}
variables
{
global:
0: banlist
1: runnertext
2: reintext
3: spawned
4: NOBAN
player:
0: jumpheight
}
rule("---- EDIT NO-BAN LIST HERE ----")
{
event
{
Ongoing - Global;
}
actions
{
"Click the [+] and change \"Null\" to \"Custom String\" to add more people"
Global.NOBAN = Array(Custom String("WildByte"), Null);
}
}
rule("died")
{
event
{
Ongoing - Each Player;
Team 1;
All;
}
conditions
{
Is Dead(Event Player) == True;
Has Spawned(Event Player) == True;
Host Player != Event Player;
Array Contains(Global.NOBAN, Custom String("{0}", Event Player)) == False;
}
actions
{
Small Message(All Players(All Teams), Custom String("{0} has been banned!", Event Player));
Modify Global Variable(banlist, Append To Array, Custom String("{0}", Event Player));
Play Effect(All Players(All Teams), Explosion Sound, Color(White), Event Player, 1000);
Remove Player(Event Player);
}
}
rule("match time")
{
event
{
Ongoing - Global;
}
conditions
{
Has Spawned(All Players(Team 2)) == True;
}
actions
{
Set Match Time(Workshop Setting Real(Custom String("Game"), Custom String("match time"), 4, 2, 15, 0) * 60);
Global.banlist = Empty Array;
Disable Built-In Game Mode Completion;
Disable Built-In Game Mode Respawning(All Players(Team 1));
Enable Death Spectate All Players(All Players(All Teams));
}
}
rule("banlist")
{
event
{
Ongoing - Each Player;
All;
All;
}
conditions
{
Array Contains(Global.banlist, Custom String("{0}", Event Player)) == True;
}
actions
{
Remove Player(Event Player);
}
}
rule("rein respawn")
{
event
{
Ongoing - Each Player;
Team 2;
All;
}
conditions
{
Is Dead(Event Player) == True;
}
actions
{
Wait(2.800, Ignore Condition);
Respawn(Event Player);
}
}
rule("team 1 win")
{
event
{
Ongoing - Global;
}
conditions
{
~~Match Time <= Null;~~
(Match Time <= Null || Is Dead(All Players(Team 2))) == True;
Is True For Any(All Players(Team 1), Has Spawned(Current Array Element)) == True;
}
actions
{
Declare Team Victory(Team 1);
}
}
rule("team 2 win")
{
event
{
Ongoing - Global;
}
conditions
{
Number Of Players(Team 1) - Number Of Dead Players(Team 1) <= Null;
Global.spawned == True;
}
actions
{
Wait(1, Ignore Condition);
Declare Team Victory(Team 2);
Wait(7, Ignore Condition);
Restart Match;
}
}
rule("reinhardt stats")
{
event
{
Ongoing - Each Player;
Team 2;
All;
}
actions
{
If(Workshop Setting Toggle(Custom String("Game"), Custom String("Reinhardt has high knockback"), True, 0));
Set Knockback Dealt(Event Player, 800);
End;
}
}
rule("setup")
{
event
{
Ongoing - Each Player;
All;
All;
}
conditions
{
Has Spawned(Event Player) == True;
}
actions
{
If(Team Of(Event Player) == Team 1);
Set Objective Description(Event Player, Random Value In Array(Global.runnertext), Visible To);
Global.spawned = True;
While(Workshop Setting Toggle(Custom String("Game"), Custom String("Runners Can See Reinhardt"), True, 2));
Start Forcing Player Outlines(All Players(Team 1), All Players(Team 2), True, Color(Red), Always);
Wait(0.250, Ignore Condition);
End;
Else;
Set Objective Description(Event Player, Random Value In Array(Global.reintext), Visible To);
If(Workshop Setting Toggle(Custom String("Game"), Custom String("Reinhardt scales by damage"), True, 1));
Start Scaling Player(Event Player, Player Stat(Event Player, All Damage Dealt) / 500 * 0.050 + 1, True);
End;
While(Workshop Setting Toggle(Custom String("Game"), Custom String("Reinhardt Can See Runners"), True, 2));
Start Forcing Player Outlines(All Players(Team 2), All Players(Team 1), True, Color(Red), Always);
Wait(0.250, Ignore Condition);
End;
}
}
rule("global setup")
{
event
{
Ongoing - Global;
}
actions
{
Global.runnertext = Array(Custom String("just run"), Custom String("book it"), Custom String("rein is banhammer"), Custom String(
"GOGOGOGOGO"), Custom String("rein is going to ban you"), Custom String("cheese it"));
Global.reintext = Array(Custom String("ban thine runners"), Custom String("smack the enemies before time"), Custom String(
"get em"), Custom String("hammer time"), Custom String("smack thine runners"));
Create HUD Text(All Players(All Teams), Null, Custom String("Code: RRXXH"), Custom String("Banhammer by NyaWalking"), Left, False,
Color(White), Color(White), Color(White), Visible To and String, Visible Always);
Pause Match Time;
Create HUD Text(All Players(Team 2), Ability Icon String(Hero(Baptiste), Button(Crouch)), Custom String(
"^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^"), Custom String("Hold [{0}] to charge jump", Input Binding String(Button(Crouch))),
Right, False, Color(Red), Color(White), Color(Red), Visible To and String, Default Visibility);
Create HUD Text(All Players(Team 1), Ability Icon String(Hero(Sombra), Button(Ability 1)), Custom String(
"^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^"), Custom String("run from rein and don't die"), Right, False, Color(Aqua), Color(White),
Color(Aqua), Visible To and String, Default Visibility);
}
}
rule("pause time")
{
event
{
Ongoing - Global;
}
conditions
{
Is True For All(All Players(Team 1), Is In Spawn Room(Current Array Element)) == True;
}
actions
{
Pause Match Time;
Wait Until(!Is True For All(All Players(Team 1), Is In Spawn Room(Current Array Element)), 99999);
Unpause Match Time;
}
}
rule("spawn room kick warning")
{
event
{
Ongoing - Each Player;
Team 1;
All;
}
conditions
{
Is In Spawn Room(Event Player) == True;
Has Spawned(Event Player) == True;
}
actions
{
Wait(20, Abort When False);
Small Message(Event Player, Custom String("you will be kicked in 10 seconds if you do not leave"));
Wait(10, Abort When False);
Small Message(All Players(All Teams), Custom String("{0} has been banned!", Event Player));
Modify Global Variable(banlist, Append To Array, Custom String("{0}", Event Player));
Remove Player(Event Player);
}
}
rule("rein spawn room")
{
event
{
Ongoing - Each Player;
All;
Reinhardt;
}
conditions
{
Is In Spawn Room(Event Player) == True;
}
actions
{
Set Move Speed(Event Player, 33.333);
Wait Until(!Is In Spawn Room(Event Player), 99999);
Set Move Speed(Event Player, 100);
Big Message(All Players(All Teams), Custom String("The Rein is Free!"));
}
}
rule("runners spawn room")
{
event
{
Ongoing - Each Player;
Team 1;
All;
}
conditions
{
Is In Spawn Room(Event Player) == True;
}
actions
{
Set Move Speed(Event Player, 200);
Wait Until(!Is In Spawn Room(Event Player), 99999);
Wait(2.800, Ignore Condition);
Set Move Speed(Event Player, 100);
}
}
rule("rein freeze")
{
event
{
Ongoing - Each Player;
Team 2;
All;
}
conditions
{
Global.spawned == False;
}
actions
{
Set Status(Event Player, Null, Rooted, 9999);
Wait Until(Global.spawned, 99999);
Clear Status(Event Player, Rooted);
}
}
rule("rein charge jump")
{
event
{
Ongoing - Each Player;
All;
Reinhardt;
}
conditions
{
Is Crouching(Event Player) == True;
}
actions
{
Event Player.jumpheight = 100;
While(Is Crouching(Event Player) && Event Player.jumpheight <= 300);
Event Player.jumpheight += 2.500;
Wait(0.050, Ignore Condition);
End;
Wait Until(!Is Crouching(Event Player), 99999);
Set Jump Vertical Speed(Event Player, Event Player.jumpheight);
Wait Until(Is Jumping(Event Player), 99999);
Set Jump Vertical Speed(Event Player, 100);
}
}
rule("sombra invis")
{
event
{
Ongoing - Each Player;
All;
Sombra;
}
conditions
{
Is Using Ability 1(Event Player) == True;
}
actions
{
Wait(4, Abort When False);
Press Button(Event Player, Button(Ability 1));
}
}
rule("rein too big")
{
event
{
Ongoing - Each Player;
All;
Reinhardt;
}
conditions
{
Player Stat(Event Player, All Damage Dealt) / 500 * 0.050 > 0.500;
}
actions
{
Disable Movement Collision With Players(Event Player);
}
}
rule("rein heal")
{
event
{
Player Took Damage;
All;
Reinhardt;
}
conditions
{
Workshop Setting Toggle(Custom String("Game"), Custom String("Rein Can Be Killed"), False, 5) == False;
}
actions
{
Set Player Health(Event Player, 10000);
Damage(Attacker, Null, Event Damage / Random Integer(5, 15));
Apply Impulse(Attacker, Direction From Angles(Horizontal Angle From Direction(Event Direction) * -1, Vertical Angle From Direction(
Event Direction)), Event Damage / Random Integer(5, 15), To World, Cancel Contrary Motion);
}
}
rule("rein damage")
{
event
{
Player Dealt Damage;
Team 2;
All;
}
actions
{
Play Effect(All Players(All Teams), Explosion Sound, Color(White), Victim, 200);
}
}
rule("no rein")
{
event
{
Ongoing - Global;
}
conditions
{
Number Of Players(Team 2) <= Null;
Number Of Players(Team 1) >= 2;
}
actions
{
Move Player to Team(Random Value In Array(All Players(Team 1)), Team 2, Empty Array);
}
}
rule("start timer again")
{
event
{
Ongoing - Global;
}
conditions
{
Global.spawned == True;
}
actions
{
Unpause Match Time;
}
}

Comparing difference between RRXXH 17JYW - 1.3 RRXXH - 1.3 RRXXH - 1.3 RRXXH - 1.2 RRXXH - 1.1 RRXXH - 1.0 and RRXXH 17JYW - 1.3 RRXXH - 1.3 RRXXH - 1.3 RRXXH - 1.2 RRXXH - 1.1 RRXXH - 1.0

Comparing difference between
RRXXH
and
RRXXH